{
  lib,
  buildGoModule,
  fetchFromGitHub,
  nix-update-script,
  versionCheckHook,
}:
buildGoModule (finalAttrs: {
  pname = "chirpstack-gateway-bridge";
  version = "4.1.2";

  src = fetchFromGitHub {
    owner = "chirpstack";
    repo = "chirpstack-gateway-bridge";
    rev = "v${finalAttrs.version}";
    hash = "sha256-3rdpIqiO6D5+JntJm2GQlnH6zh3s3DOzpaxr06PR+K4=";
  };

  vendorHash = "sha256-nDbUem9WV2DClrUBTjDvz+jUqqkQI+QGuv8h39EBs9E=";

  ldflags = [
    "-s"
    "-w"
    "-X main.version=v${finalAttrs.version}"
  ];

  nativeInstallCheckInputs = [ versionCheckHook ];

  doInstallCheck = true;
  versionCheckProgramArg = "version";
  checkFlags = [
    "-skip=TestMQTTBackend" # Depends on external MQTT broker
  ];

  passthru.updateScript = nix-update-script { };

  meta = {
    description = "Gateway Bridge abstracts Packet Forwarder protocols into Protobuf or JSON over MQTT";
    homepage = "https://www.chirpstack.io/";
    license = lib.licenses.mit;
    maintainers = [ lib.maintainers.stv0g ];
    mainProgram = "chirpstack-gateway-bridge";
  };
})